
**Using moving annual total calculations**

A common way to aggregate data over several months is by using the moving annual total instead of the year-to-date. The moving annual total includes the last 12 months of data. For example, the moving annual total for March 2008 includes data from April 2007 to March 2008.



The moving annual total uses [**DATESINPERIOD**](https://dax.guide/datesinperiod/?aff=dax-patterns) to select the previous year:

Sales MAT :=

IF (

    [ShowValueForDates],

    CALCULATE (

        [Sales Amount],

        DATESINPERIOD (

            'Date'[Date],

            MAX ( 'Date'[Date] ),

            -1,


            YEAR

        )

    )

)

## Moving annual total growth



Sales PYMAT :=

IF (

    [ShowValueForDates],

    CALCULATE (

        [Sales MAT],

        DATEADD ( 'Date'[Date], -1, YEAR )

    )

)

Sales MATG :=

VAR ValueCurrentPeriod = [Sales MAT]

VAR ValuePreviousPeriod = [Sales PYMAT]

VAR Result =

    IF (

        NOT ISBLANK ( ValueCurrentPeriod )

            && NOT ISBLANK ( ValuePreviousPeriod ),

        ValueCurrentPeriod - ValuePreviousPeriod

    )

RETURN

    Result

Sales MATG % :=

DIVIDE (

    [Sales MATG],

    [Sales PYMAT]

)

The Sales PYMAT measure can also be written using [**SAMEPERIODLASTYEAR**](https://dax.guide/sameperiodlastyear/?aff=dax-patterns) as in the following example, which internally uses [**DATEADD**](https://dax.guide/dateadd/?aff=dax-patterns) as in the previous example:

Sales PYMAT (2) :=

IF (

    [ShowValueForDates],

    CALCULATE (

        [Sales MAT],

        SAMEPERIODLASTYEAR ( 'Date'[Date] )

    )

)